enable wgpu_binding_array;

struct Instance {
	transform:   mat2x2<f32>,
	translation: vec2<f32>,
	uv_offset:   vec2<f32>,
	uv_size:     vec2<f32>,
	tex_id:      u32,
	_pad:        u32,
}

struct VertexOutput {
	@builtin(position)              position: vec4<f32>,
	@location(0)                    uv:       vec2<f32>,
	@location(1) @interpolate(flat) tex_id:   u32,
}

@group(0) @binding(0) var<storage, read> instances: array<Instance>;

@group(1) @binding(0) var tex_sampler: sampler;
@group(1) @binding(1) var font_tex:    texture_2d<f32>;
@group(1) @binding(2) var image_texs:  binding_array<texture_2d<f32>, 5>;

@vertex
fn vs_main(
	@builtin(vertex_index)   in_vertex_index:   u32,
	@builtin(instance_index) in_instance_index: u32,
) -> VertexOutput {
	let uv = vec2<f32>(f32((in_vertex_index << 1) & 2), f32(in_vertex_index & 2)) / 2.0;
	let instance = instances[in_instance_index];

	var out: VertexOutput;
	out.position = vec4<f32>(instance.transform * (uv - 0.5) + instance.translation, 0.0, 1.0);
	out.uv = instance.uv_offset + uv * instance.uv_size;
	out.tex_id = instance.tex_id;

	return out;
}

@fragment
fn fs_main(in: VertexOutput) -> @location(0) vec4<f32> {
	if in.tex_id >= 5u {
		return vec4<f32>(1.0, 1.0, 1.0, textureSampleLevel(font_tex, tex_sampler, in.uv, 0.0).r);
	}
	return textureSampleLevel(image_texs[in.tex_id], tex_sampler, in.uv, 0.0);
}